If this in phoenix templates? If so then you likely want to implement Phoenix.HTML.Safe for the Money struct.

For posterity, my function now looks like this:

  defimpl Phoenix.HTML.Safe, for: Money do
    def to_iodata(%Money{amount: %Decimal{coef: coef, exp: 0}} = money) when is_integer(coef) do
      money
      |> Money.to_string!(fractional_digits: 0)
      |> HTML.Safe.to_iodata()
    end

    @simple_currencies [:USD, :EUR]
    def to_iodata(%Money{amount: %Decimal{coef: coef, exp: -2}, currency: currency} = money)
        when rem(coef, 100) == 0 and currency in @simple_currencies do
        money
        |> Money.to_string!(fractional_digits: 0)
        |> HTML.Safe.to_iodata()
      end

    def to_iodata(money) do
      money
      |> Money.to_string!()
      |> HTML.Safe.to_iodata()
    end
  end

Oh, interesting. I’ll look at adding that as an implementation on the next version of ex_money. I’m only just now getting back to web dev and hadn’t realised there is both the Html.Safe and Phoenix.HTML.Safe protocols (and maybe there isn’t a difference any more!)

D’Oh, should have read my own code first. This is the implementation:

  defimpl Phoenix.HTML.Safe, for: Money do
    def to_iodata(money) do
      Phoenix.HTML.Safe.to_iodata(Money.to_string!(money))
    end
  end

Does it not do what you expect?

You can actually store formatting options in a Money.t if you need - that capability was primarily added to support this protocol. Of course if thats not enough you can certainly do your own implementation as you showed.

Example

iex> m = Money.new(:USD, 1234, format: :long)
#Money<:USD, 1234>
iex> Money.to_string m                       
{:ok, "1,234 US dollars"}

Thanks for the explanation and I understand the use case. Let me think on this and revert soon.

As of commit 8c14f4f there is a compile-time option to configure whether or not the default protocol implementation is defined. The changelog entry is:

• Add :define_phoenix_html_safe as a compile-time configuration option. The default is true. If set to a falsy value then the default protocol implementation will not be generated and users can define their own implementation.

Basically, in config.exs and friends:

config :ex_money,
  define_phoenix_html_safe: false

The commit is on a development branch that will be published Lunar New Year’s Day (next Tuesday) and therefore can’t really be used easily as a GitHub dependency.

If the need becomes urgent I can do a backport to the current main branch and publish a release, but I’d prefer to wait until Tuesday if thats possible. Let me know?