Fl4m3Ph03n1x

How to define Macro for a new Type?

Background

So, I am playing around with a concept named “NewType” and I am taking inspiration from languages like F# and Scala.

My objective, for learning purposes mostly, is to build a macro that makes creating this abstraction something that takes no more than a single line of code.

Intended usage

I would like to create a macro that allows me to do something like this:

defmodule User do
  require NewType # an absolutely original name for the macro :D

  deftype Name, String.t() # Usage of said macro. Here I am defining a new type called "Name"

  @enforce_keys [:name, :age]
  defstruct [:name, :age]
  @type t :: %__MODULE__{
          name: Name.t,
          age: integer()
        }

  @spec new(Name.t, integer) :: User.t
  def new(name, age), do: %User{name: name, age, age}  
end

And now, here is how I could create a User:

defmodule Test do
  alias User
  import User.Name

  @spec run :: User.t
  def run do
    name = Name("John")
    User.new(name, 25)
  end
end

How to implement this interface?

This interface might remind you a little of the Record interface. That’s because I think its API has some good ideas I would like to explore.

So, as a starting point I tried reading the source code for Record, but I was not really able to pick it up and use it to create an implementation for my use case, mainly because I don’t need/want to interface with Erlang records at all.

So, an implementation possibility would be to, under the hood, turn this into a tuple:

defmodule NewType do
  defmacro new(name, val) do
    quote do
      NewType.to_tuple(unquote(name), unquote(val))
    end
  end

  def to_tuple(name, val), do: {String.to_atom(name), val}
end

However, this is miles away from the interface I want to create …

Questions

Using Elixir macros, is it possible to create the API I am aiming for?
How can I change my code to achieve something like Name("John")?

9 comments

#algebraic_data_type #macro #types #defmacro

7 2015 9

2022-04-06 13:26:34 UTC

Marked As Solved

Fl4m3Ph03n1x

My Answer

After reading more about macros in Elixir, talking to the community and reading about NewType, I have refined my ideas. While the exact implementation of my original idea is not possible, with some changes you can still get the core benefit of NewType.

Changes to original idea

No usage of Name("John") syntax. As explained in this post this syntax is not valid in Elixir.
No defguard. Because the type is @opaque it is not possible to have a guard that analyses the internal structure of the data without having dialyzer complaining. Since the main goal here is to have Dialyzer help me detect issues, and since the internal structure of the opaque data can only be analyzed by functions that belong to the module itself, this means this idea is not possible.
No verification on data type when invoking new. Originally I thought about having some verification mechanism, but this is not necessary, since dialyzer will let the user know if the user is invoking new with an incorrect parameter.
No self-generated functions. Instead of having Age.age? or Name.name? I have opted for the more general NewType.is_type?/2, which will accomplish the same and is more general.

Code

With these changes in mind, this is the macro I came up with:

defmodule NewType do
  defmacro deftype(name, type) do
    quote do
      defmodule unquote(name) do
        @opaque t :: {unquote(name), unquote(type)}

        @spec new(value :: unquote(type)) :: t
        def new(value), do: {unquote(name), value}

        @spec extract(new_type :: t) :: unquote(type)
        def extract({unquote(name), value}), do: value
      end
    end
  end

  @spec is_type?(data :: {atom, any}, new_type :: atom) :: boolean
  def is_type?({type, _data}, new_type) when type == new_type, do: true
  def is_type?(_data, _new_type), do: false
end

Which can be used like:

type.ex:

defmodule Type do
  import NewType

  deftype Name, String.t()
end

test.ex:

defmodule Test do
  alias Type.Name

  @spec print(Name.t()) :: binary
  def print(name), do: Name.extract(name)

  def run do
    arg = 1
    name = Name.new(arg) # dialyzer detects error !
    {:ok, name}
  end
end

Post #10

Also Liked

LostKobrakai

That’s not possible with the uppercase first letter. Any call to a macro or function needs to start with a non uppercase letter.

Non-qualified calls, such as add(1, 2) , must start with an underscore or a Unicode letter that is not in uppercase or titlecase.

Qualified calls, such as Math.add(1, 2) , must start with an underscore or a Unicode letter that is not in uppercase or titlecase.

Syntax reference

Post #2

LostKobrakai

You can generate modules, but you cannot “call” modules. You can only call macros or functions. So Name("…") is not valid elixir syntax – Name.new("…") is.

Post #4

lud

Yes.

Start by writing the Name module by hand. That will show you what your macro would have to generate.

Post #6

benwilson512

Author of Craft GraphQL APIs in Elixir with Absinthe

Probably. Mutually recursive types however may well be difficult to do with this.

A lot of macro work. I’d start with the Metaprogramming Elixir book.

As an aside though: I’d seriously consider looking at Gleam. It’s a BEAM language w/ static types. If you want to push forward the boundaries of what will be possible with types on the BEAM I imagine that work in that ecosystem is going to be more fruitful than attempting to make it work in Elixir. If Jose tried to make it work and failed, I would think long and hard about taking it on yourself.

Post #8