Not sure if this is elegant, but this one way of doing it

defmodule Example do
  def cleanup(data, source) when is_map(data) do
    if filter?(data, source) do
      %{"source" => "", "value" => ""}
    else
      Map.new(data, fn {key, value} ->
        {key, cleanup(value, source)}
      end)
    end
  end

  def cleanup([hd | tail], source) do
    list = if filter?(hd, source), do: tail, else: [hd | tail]
    Enum.map(list, &cleanup(&1, source))
  end

  def cleanup(data, _source), do: data

  defp filter?(data, source), do: match?(%{"source" => ^source}, data)
end

This is a fairly elegant solution, IMO:

defmodule Cleanup do
  def cleanup(data, source_id) do
    case data do
      %{"source" => ^source_id} ->
        %{"source" => "", "value" => ""}

      %{} ->
        Map.new(data, fn {k, v} -> {k, cleanup(v, source_id)} end)

      [_ | _] ->
        data
        |> Enum.reject(&match?(%{"source" => ^source_id}, &1))
        |> Enum.map(fn v -> cleanup(v, source_id) end)

      _ ->
        data
    end
  end
end

Just like the data structure, the code is recursive (for handling list elements and child maps).

The most unique part of this is the middle line in the list case:

Enum.reject(data, &match?(%{"source" => ^source_id}, &1))

Without that line, cleanup simply replaces every map with `“source” => ^source_id" with the empty version

Is it possible to change the data structure?

Some points that would make me think twice are

• arbitrary keys (Most of the time I’d prefer %{key: "foo", value: "bar"} over %{foo: "bar"})
• maps may occur in lists and as single item (why not lists of one instead?)
• nested structure, most of the times a flat structure is easier to handle

Its impossible to say if that would be better not knowing what you are doing. But I found that thinking twice about the data structures can lead to way simpler code.